import mods.ic2.Macerator;
import mods.mekanism.Crusher;

#Remove Nano-suit recipes
recipes.remove(<IC2:itemArmorNanoHelmet>);
recipes.remove(<IC2:itemArmorNanoChestplate>);
recipes.remove(<IC2:itemArmorNanoLegs>);
recipes.remove(<IC2:itemArmorNanoBoots>);

#Remove Q-Suit recipes
recipes.remove(<IC2:itemArmorQuantumHelmet>);
recipes.remove(<IC2:itemArmorQuantumChestplate>);
recipes.remove(<IC2:itemArmorQuantumLegs>);
recipes.remove(<IC2:itemArmorQuantumBoots>);

#Change water mill recipe
var mill = <IC2:blockGenerator:2>;
var alloy = <IC2:itemPartAlloy>;
var shaft = <IC2:itemRecipePart:12>;
var kinetic_gen = <IC2:blockGenerator:9>;

recipes.remove(mill);
recipes.addShaped(mill, [[alloy, shaft, alloy], [shaft, kinetic_gen, shaft], [alloy, shaft, alloy]]);

#Remove IC2 blast furnace
recipes.remove(<IC2:blockMachine3:1>);

#Energium Dust recipe
var energium = <IC2:itemDust2:2>;
var d_dust = <IC2:itemDust2:1>;
val redstone = <minecraft:redstone>;
val glowstone = <minecraft:glowstone_dust>;

recipes.remove(energium);
recipes.addShaped(energium * 9, [[redstone, d_dust, redstone], [d_dust, glowstone, d_dust], [redstone, d_dust, redstone]]);

#Glass fibre recipe
var fib_cable = <IC2:itemCable:9>;
val glass = <minecraft:glass:0>;
var electrum = <ore:dustElectrum>;

recipes.remove(fib_cable);
recipes.addShaped(fib_cable, [[glass, glass, glass], [energium, electrum, energium], [glass, glass, glass]]);

#Remove IC2 solar panel :(
recipes.remove(<IC2:blockGenerator:3>);

#Remove nuke
recipes.remove(<IC2:blockNuke>);

#Remove all the IC2 reactor blocks :( X6
recipes.remove(<IC2:blockGenerator:5>);
recipes.remove(<IC2:blockReactorChamber>);
recipes.remove(<IC2:blockreactorvessel>);
recipes.remove(<IC2:blockReactorRedstonePort>);
recipes.remove(<IC2:blockReactorAccessHatch>);
recipes.remove(<IC2:blockReactorFluidPort>);

#Change macerator recipe
var circuit = <ore:circuitBasic>;
var blade = <IC2:itemDiamondBlockCuttingBlade>;
var macerator = <IC2:blockMachine:3>;
var mac_block = <IC2:blockMachine:0>;

recipes.remove(macerator);
recipes.addShaped(macerator, [[blade], [circuit], [mac_block]]);

#Tweak macerator recipes to output more ore for iron, copper and tin
#Macerator.addRecipe(<IC2:itemCrushedOre:0> * 3, <minecraft:iron_ore>); Commented out:
#Macerator.addRecipe(<IC2:itemCrushedOre:1> * 3, <ore:oreCopper>); Doesn't work
#Macerator.addRecipe(<IC2:itemCrushedOre:3> * 3, <ore:oreTin>); due to API limitations

#Remove Mek bronze recipe
mods.mekanism.Infuser.removeRecipe(<Mekanism:Ingot:2>);
mods.mekanism.Infuser.removeRecipe(<Mekanism:Ingot:2>);
mods.mekanism.Infuser.removeRecipe(<Mekanism:Ingot:2>);
mods.mekanism.Infuser.removeRecipe(<Mekanism:Ingot:2>);

#Changed Mek heat generator recipe
val diamond = <ore:gemDiamond>;
var osmium = <ore:ingotOsmium>;
var solid_gen = <IC2:blockHeatGenerator:0>;
var stirling_gen = <IC2:blockGenerator:8>;
var fluid_gen = <IC2:blockHeatGenerator:1>;
var heat_gen = <MekanismGenerators:Generator:0>;

recipes.remove(heat_gen);
recipes.addShaped(heat_gen, [[diamond, solid_gen, diamond], [alloy, stirling_gen, alloy], [osmium, fluid_gen, osmium]]);

#Change Mek solar panel item recipe
var pane = <minecraft:glass_pane:0>;
var silicon = <ore:itemSilicon>;
var solar_item = <MekanismGenerators:SolarPanel>;
val steel = <ore:ingotSteel>;

recipes.remove(solar_item);
recipes.addShaped(solar_item, [[pane, pane, pane], [redstone, silicon, redstone], [osmium, steel, osmium]]);

#Change Mek advanced solar recipe
var solar =  <MekanismGenerators:Generator:1>;
var adv_solar = <MekanismGenerators:Generator:5>;

recipes.remove(adv_solar);
recipes.addShaped(adv_solar, [[solar, diamond, solar], [solar, diamond, solar], [steel, steel, steel]]);

#Change bio generator recipe
val iron = <ore:ingotIron>;
var enrich = <Mekanism:EnrichedAlloy>;
var bio_gen = <MekanismGenerators:Generator:4>;

recipes.remove(bio_gen);
recipes.addShaped(bio_gen, [[redstone, enrich, redstone], [heat_gen, circuit, heat_gen], [steel, enrich, steel]]);

#Change mek windmill recipe
var windmill = <MekanismGenerators:Generator:6>;
var rotor = <IC2:itemwcarbonrotor>;
var tablet = <Mekanism:EnergyTablet:*>;
var kinetic_wind_gen = <IC2:blockKineticGenerator:0>;

recipes.remove(windmill);
recipes.addShaped(windmill, [[null, rotor, null], [osmium, kinetic_wind_gen, osmium], [tablet, kinetic_gen, tablet]]);

#Change gas-burning generator recipe
var gas_gen = <MekanismGenerators:Generator:3>;
var steel_case = <Mekanism:BasicBlock:8>;
var electro_core = <Mekanism:ElectrolyticCore>;

recipes.remove(gas_gen);
recipes.addShaped(gas_gen, [[osmium, heat_gen, osmium], [steel_case, electro_core, steel_case], [osmium, heat_gen, osmium]]);

#Change metal-infuser recipe
var infuser = <Mekanism:MachineBlock:8>;
var blast_brick = <Railcraft:tile.railcraft.machine.alpha:12>;

recipes.remove(infuser);
recipes.addShaped(infuser, [[iron, blast_brick, iron], [redstone, steel, redstone], [iron, blast_brick, iron]]);

#Change ultimate cable recipe
var ulti_cable = <Mekanism:PartTransmitter:3>;
var elite_cable = <Mekanism:PartTransmitter:2>;
var atomic = <Mekanism:AtomicAlloy>;
var dia_pipe = <BuildCraft|Transport:item.buildcraftPipe.pipepowerdiamond>;

recipes.remove(ulti_cable);
recipes.addShaped(ulti_cable, [[atomic, fib_cable, atomic], [dia_pipe, elite_cable, dia_pipe], [atomic, fib_cable, atomic]]);

#Change electric track recipe
var adv_rail = <Railcraft:part.rail:1>;
var ele_rail = <Railcraft:part.rail:5>;
var rebar = <Railcraft:part.rebar>;

mods.railcraft.Rolling.removeRecipe(ele_rail);
mods.railcraft.Rolling.addShaped(ele_rail * 6, [[adv_rail, energium, adv_rail], [adv_rail, alloy, adv_rail], [adv_rail, energium, adv_rail]]);
mods.railcraft.Rolling.removeRecipe(<Railcraft:part.rebar> * 2);
mods.railcraft.Rolling.removeRecipe(<Railcraft:part.rebar> * 4);
mods.railcraft.Rolling.removeRecipe(<Railcraft:part.rebar> * 4);
mods.railcraft.Rolling.removeRecipe(<Railcraft:part.rebar> * 8);
mods.railcraft.Rolling.removeRecipe(<Railcraft:part.rebar> * 8);
mods.railcraft.Rolling.removeRecipe(<Railcraft:part.rebar> * 16);
mods.railcraft.Rolling.removeRecipe(<Railcraft:part.rebar> * 16);
mods.railcraft.Rolling.removeRecipe(<Railcraft:part.rebar> * 48);
mods.railcraft.Rolling.addShaped(rebar * 32, [[null, null, <IC2:itemPartAlloy>], [null, <IC2:itemPartAlloy>, null], [null, null, <IC2:itemPartAlloy>]]);


#Change electric tree-tap recipe
var ele_treetap_any = <IC2:itemTreetapElectric>;
var ele_treetap = <IC2:itemTreetapElectric:26>;
var small_unit = <IC2:itemRecipePart:3>;
var iron_plate = <ore:plateIron>;

recipes.remove(ele_treetap_any);
recipes.addShaped(ele_treetap, [[null, iron_plate, null], [iron_plate, iron_plate, small_unit], [iron_plate, null, null]]);

#Change extractor recipe (not completely sure why)
var extractor = <IC2:blockMachine:4>;
var Cell = <IC2:itemFluidCell>;
var treetap = <IC2:itemTreetap:0>;

recipes.remove(extractor);
recipes.addShaped(extractor, [[Cell, mac_block, Cell], [Cell, circuit, Cell]]);

#Change electric locomotive recipe
var ele_loco = <Railcraft:cart.loco.electric>.withTag({model:"railcraft:default"});
var lamp = <minecraft:redstone_lamp>;
var cart = <minecraft:minecart>;
var steel_gear = <Railcraft:part.gear:2>;
var energy_crystal = <IC2:itemBatCrystal:*>;

recipes.remove(ele_loco);
recipes.addShaped(ele_loco, [[lamp, alloy, null], [alloy, energy_crystal, alloy], [steel_gear, cart, steel_gear]]);

#Change metal former recipe
var anvil = <Railcraft:tile.railcraft.anvil:*>;
var metal_former = <IC2:blockMachine2:4>;

recipes.remove(metal_former);
recipes.addShaped(metal_former, [[anvil], [circuit], [mac_block]]);

#Change the carbon kinetic wind generator rotor recipe
var carbon_blade = <IC2:itemRecipePart:9>;

recipes.remove(rotor);
recipes.addShaped(rotor, [[diamond, carbon_blade, diamond], [carbon_blade, shaft, carbon_blade], [diamond, carbon_blade, diamond]]);

#Change electric feeder unit recipe
var feeder = <Railcraft:tile.railcraft.machine.epsilon:0>;
var ingotelectrum = <ore:ingotElectrum>;

recipes.remove(<Railcraft:tile.railcraft.machine.epsilon:4>);

recipes.remove(feeder);
recipes.addShaped(feeder, [[alloy, ingotelectrum, alloy], [ingotelectrum, energy_crystal, ingotelectrum], [alloy, ingotelectrum, alloy]]);

#Change Quarry and Mining Boost ring recipes
var Ddrill = <IC2:itemToolDDrill>.anyDamage();
var ring = <Thaumcraft:ItemBaubleBlanks:1>;

recipes.remove(<BuildCraft|Factory:machineBlock>);
recipes.addShaped(<BuildCraft|Factory:machineBlock>, [[steel, dia_pipe, steel], [circuit, mac_block, circuit], [null, Ddrill, null]]);

recipes.addShaped(<Baubles:Ring>, [[diamond, diamond, diamond], [Ddrill, ring, Ddrill], [diamond, diamond, diamond]]);

#Change basic machine casing recipe
var steel_plate = <ore:plateSteel>;
steel_plate.add(<Railcraft:part.plate:1>);

recipes.remove(mac_block);
recipes.addShaped(mac_block, [[steel_plate, steel_plate, steel_plate], [steel_plate, null, steel_plate], [steel_plate, steel_plate, steel_plate]]);

#Nerf the transporter recipe, but why won't you remove the old recipe :c
var diamond_pipe = <BuildCraft|Transport:item.buildcraftPipe.pipeitemsdiamond>;
var logi_pipe = <Mekanism:PartTransmitter:9>;

recipes.remove(<Mekanism:PartTransmitter:9>);
recipes.addShaped(<Mekanism:PartTransmitter:9>, [[null, circuit, null], [steel_plate, diamond_pipe, steel_plate], [null, circuit, null]]);

#Change logical sorter recipe
var sorter = <Mekanism:MachineBlock:15>;
var bars = <minecraft:iron_bars>;

recipes.remove(sorter);
recipes.addShaped(sorter, [[iron, bars, iron], [iron, circuit, iron], [iron, logi_pipe, iron]]);

#Change IC2 circuit recipe
var IC2_circuit = <IC2:itemPartCircuit:0>;
var red_alloy = <ore:ingotRedAlloy>;
var copper_cable = <IC2:itemCable:0>;

recipes.remove(IC2_circuit);
recipes.addShaped(IC2_circuit, [[copper_cable, copper_cable, copper_cable], [redstone, red_alloy, redstone], [copper_cable, copper_cable, copper_cable]]);

#Change iron furnace recipe
var iron_furnace = <IC2:blockMachine:1>;

recipes.remove(iron_furnace);
recipes.addShaped(iron_furnace, [[<minecraft:netherrack>], [mac_block], [<minecraft:furnace>]]);

#Change mixed metal ingot recipe
var mixed = <IC2:itemIngot:4>;
var tin_plate = <ore:plateTin>;
var bronze_plate = <ore:plateBronze>;

recipes.remove(mixed);
recipes.addShaped(mixed * 2, [[steel_plate, steel_plate, steel_plate], [bronze_plate, bronze_plate, bronze_plate], [tin_plate, tin_plate, tin_plate]]);

#Change stone gear recipe
var stone_gear = <BuildCraft|Core:stoneGearItem>;
var cobble = <ore:cobblestone>;

recipes.remove(stone_gear);
recipes.addShaped(stone_gear, [[null, cobble, null], [cobble, <minecraft:stone_slab:3>, cobble], [null, cobble, null]]);

#add recipe for the Gold gear from BC

var iron_gear = <BuildCraft|Core:ironGearItem>;
var gold_gear = <BuildCraft|Core:goldGearItem>;
var diamond_gear = <BuildCraft|Core:diamondGearItem>;

recipes.addShaped(iron_gear, [[null, <minecraft:iron_ingot>, null], [<minecraft:iron_ingot>, stone_gear, <minecraft:iron_ingot>], [null, <minecraft:iron_ingot>, null]]);
recipes.addShaped(gold_gear, [[null, <minecraft:gold_ingot>, null], [<minecraft:gold_ingot>, iron_gear, <minecraft:gold_ingot>], [null, <minecraft:gold_ingot>, null]]);
recipes.addShaped(diamond_gear, [[null, <minecraft:diamond>, null], [<minecraft:diamond>, gold_gear, <minecraft:diamond>], [null, <minecraft:diamond>, null]]);

#Nuke gear ore dictionary...
for item in <ore:gearIron>.items {
    <ore:gearIron>.remove(item);
}
for item in <ore:gearGold>.items {
    <ore:gearGold>.remove(item);
}

var piston = <minecraft:piston>;
iron_plate.add(<Railcraft:part.plate:0>);
recipes.addShaped(<Railcraft:tile.railcraft.machine.beta:8>, [[iron_plate, iron_plate, iron_plate], [null, glass, null], [<Railcraft:part.gear:1>, piston, <Railcraft:part.gear:1>]]);

#Change rolling machine recipe
var rolling = <Railcraft:tile.railcraft.machine.alpha:8>;
var compressor = <IC2:blockMachine:5>;

recipes.remove(rolling);
recipes.addShaped(rolling, [[compressor], [mac_block], [metal_former]]);

#Change overclocker upgrade recipe
var overclocker = <IC2:upgradeModule:0>;
var coolant = <IC2:reactorCoolantSimple:0>;
var lapis_block = <ore:blockLapis>;
var gold_casing = <IC2:itemCasing:3>;

recipes.remove(overclocker);
recipes.addShaped(overclocker, [[null, lapis_block, null], [coolant, energium, coolant], [gold_casing, alloy, gold_casing]]);

#Change energy storage upgrade recipe
var energy_store = <IC2:upgradeModule:2>;
var redstone_block = <ore:blockRedstone>;

recipes.remove(energy_store);
recipes.addShaped(energy_store, [[null, redstone_block, null], [coolant, energium, coolant], [gold_casing, alloy, gold_casing]]);

#Try to remove obsidian and glowstone ingot breaking down recipes
Crusher.removeRecipe(<Mekanism:Ingot:0>);
Crusher.removeRecipe(<Mekanism:Ingot:3>);
#The best you can get, since TE4 doesn't have recipe support, and IC2 doesn't allow recipes to be removed.

#Change drill and chainsaw recipes
var drill = <IC2:itemToolDrill:26>;
var chainsaw = <IC2:itemToolChainsaw:26>;
var power_unit = <IC2:itemRecipePart:2>;

recipes.remove(drill.anyDamage());
recipes.remove(chainsaw.anyDamage());

recipes.addShaped(drill, [[null, steel_plate, null], [steel_plate, steel_plate, steel_plate], [steel_plate, power_unit, steel_plate]]);
recipes.addShaped(chainsaw, [[null, steel_plate, steel_plate], [steel_plate, steel_plate, steel_plate], [power_unit, steel_plate, null]]);

#Change electric furnace recipe
var ele_furnace = <IC2:blockMachine:2>;

recipes.remove(ele_furnace);
recipes.addShaped(ele_furnace, [[null, circuit, null], [lamp, iron_furnace, lamp]]);

#Trash + Fix Mek Circuits
circuit.remove(<Mekanism:ControlCircuit:0>);
mods.mekanism.Infuser.removeRecipe(<Mekanism:ControlCircuit:0>);
<ore:circuitAdvanced>.remove(<Mekanism:ControlCircuit:1>);
recipes.remove(<Mekanism:ControlCircuit:1>);
recipes.remove(<Mekanism:ControlCircuit:2>);
recipes.addShaped(<Mekanism:ControlCircuit:2>, [[<ore:alloyElite>, <ore:circuitAdvanced>, <ore:alloyElite>]]);

#Change pulveriser recipe
var pulveriser = <ThermalExpansion:Machine:1>.withTag({Level: 0 as byte, Augments: [{id: 4757 as short, Damage: 0 as short, Count: 1 as byte, Slot: 0}, {id: 4757 as short, Damage: 32 as short, Count: 1 as byte, Slot: 1}, {id: 4757 as short, Damage: 16 as short, Count: 1 as byte, Slot: 2}]});
var copper_gear = <ore:gearCopper>;
var basic_frame = <ThermalExpansion:Frame:0>;
var reception = <ThermalExpansion:material:1>;

recipes.removeShaped(pulveriser, [[null, piston, null], [<minecraft:flint>, basic_frame, <minecraft:flint>], [copper_gear, reception, copper_gear]]);
recipes.addShaped(pulveriser, [[null, piston, null], [diamond, basic_frame, diamond], [copper_gear, reception, copper_gear]]);

#Change crusher recipe
var crusher = <Mekanism:MachineBlock:3>;
var lava = <minecraft:lava_bucket>;

recipes.remove(crusher);
recipes.addShaped(crusher, [[redstone, circuit, redstone], [lava, macerator, lava], [redstone, circuit, redstone]]);

#Change enrichment chamber recipe
var enrichment = <Mekanism:MachineBlock:0>;

recipes.remove(enrichment);
recipes.addShaped(enrichment, [[redstone, circuit, redstone], [compressor, macerator, compressor], [redstone, circuit, redstone]]);

#Change energised smelter recipe
var smelter = <Mekanism:MachineBlock:10>;

recipes.remove(smelter);
recipes.addShaped(smelter, [[redstone, circuit, redstone], [<ore:blockGlass>, ele_furnace, <ore:blockGlass>], [redstone, circuit, redstone]]);

#Add cheaty recipe to remove AE2 in world crafting
var quartz = <ore:gemQuartz>;
var quartz_dust = <ore:dustNetherQuartz>;
var certus = <appliedenergistics2:item.ItemMultiMaterial:1>;
var certus_dust = <ore:dustCertusQuartz>;
#var fluix = <ore:crystalFluix>; Ore dictionary can't be an output
var fluix = <appliedenergistics2:item.ItemMultiMaterial:7>;
#var fluix_dust = <ore:dustFluix>; So we have to use the long method
var fluix_dust = <appliedenergistics2:item.ItemMultiMaterial:8>;

recipes.addShapeless(fluix * 2, [quartz, certus, redstone]);
recipes.addShapeless(fluix_dust * 2, [quartz_dust, certus_dust, redstone]);

#Enrich AE2 crystals
var quartzs = <minecraft:quartz>; #Why Mekanism, do you not support ore dictionary input?
var certusz = <appliedenergistics2:item.ItemMultiMaterial:1>; #WHY?!
var pure_quartz = <appliedenergistics2:item.ItemMultiMaterial:11>;
var pure_certus = <appliedenergistics2:item.ItemMultiMaterial:10>;
var pure_fluix = <appliedenergistics2:item.ItemMultiMaterial:12>;

mods.mekanism.Enrichment.addRecipe(quartzs, pure_quartz);
mods.mekanism.Enrichment.addRecipe(certusz, pure_certus);
mods.mekanism.Enrichment.addRecipe(fluix, pure_fluix);

#Fix nether and certus block recipe
var quartz_block = <minecraft:quartz_block>;
var certus_block = <appliedenergistics2:tile.BlockQuartz:0>;
var fluix_block = <appliedenergistics2:tile.BlockFluix>;

recipes.removeShaped(quartz_block, [[pure_quartz, pure_quartz, pure_quartz], [pure_quartz, null, pure_quartz], [pure_quartz, pure_quartz, pure_quartz]]);
recipes.addShaped(quartz_block, [[pure_quartz, pure_quartz], [pure_quartz, pure_quartz]]);
recipes.removeShaped(certus_block, [[pure_certus, pure_certus, pure_certus], [pure_certus, null, pure_certus], [pure_certus, pure_certus, pure_certus]]);
recipes.addShaped(certus_block, [[certus, certus], [certus, certus]]);
recipes.addShaped(certus_block, [[pure_certus, pure_certus], [pure_certus, pure_certus]]);
recipes.remove(fluix_block);
recipes.addShaped(fluix_block, [[fluix, fluix], [fluix, fluix]]);
recipes.addShaped(fluix_block, [[pure_fluix, pure_fluix], [pure_fluix, pure_fluix]]);

#Add anvil blast furnace recipe
mods.railcraft.BlastFurnace.addRecipe(<minecraft:anvil:0>, true, false, 42240, <Railcraft:tile.railcraft.anvil:0>);
mods.railcraft.BlastFurnace.addRecipe(<minecraft:anvil:1>, true, false, 42240, <Railcraft:tile.railcraft.anvil:1>);
mods.railcraft.BlastFurnace.addRecipe(<minecraft:anvil:2>, true, false, 42240, <Railcraft:tile.railcraft.anvil:2>);

#Turn the crusher into a macerator
Crusher.addRecipe(<minecraft:coal_ore>, <minecraft:coal:0> * 3);
Crusher.addRecipe(<ThermalFoundation:Ore:0>, <Mekanism:Dust:6> * 2);
Crusher.addRecipe(<ThermalFoundation:Ore:1>, <Mekanism:Dust:7> * 2);
Crusher.addRecipe(<minecraft:iron_ore>, <Mekanism:Dust:0> * 2);
Crusher.addRecipe(<ThermalFoundation:Ore:4>, <ThermalFoundation:material:36> * 2);
Crusher.addRecipe(<ThermalFoundation:Ore:3>, <Mekanism:Dust:9> * 2);
Crusher.addRecipe(<ThermalFoundation:Ore:2>, <Mekanism:Dust:8> * 2);
Crusher.addRecipe(<minecraft:redstone_ore>, redstone * 8);
Crusher.addRecipe(<minecraft:gold_ore>, <Mekanism:Dust:1> * 2);
Crusher.addRecipe(<Mekanism:OreBlock>, <Mekanism:Dust:2> * 2);
Crusher.addRecipe(<minecraft:diamond_ore>, <minecraft:diamond> * 2);
Crusher.addRecipe(<minecraft:emerald_ore>, <minecraft:emerald> * 2);
Crusher.addRecipe(<ThermalFoundation:Ore:5>, <ThermalFoundation:material:37> * 2);
Crusher.addRecipe(<ThermalFoundation:Ore:6>, <ThermalFoundation:material:38> * 2);
Crusher.addRecipe(<minecraft:quartz_ore>, <minecraft:quartz> * 4);
Crusher.addRecipe(<appliedenergistics2:tile.OreQuartz>, <appliedenergistics2:item.ItemMultiMaterial:2> * 4);
Crusher.addRecipe(<appliedenergistics2:tile.OreQuartzCharged>, <appliedenergistics2:item.ItemMultiMaterial:2> * 4);

mods.mekanism.Enrichment.removeRecipe(<appliedenergistics2:item.ItemMultiMaterial:2>);
mods.mekanism.Enrichment.removeRecipe(<appliedenergistics2:item.ItemMultiMaterial:2>);
mods.mekanism.Enrichment.removeRecipe(<appliedenergistics2:item.ItemMultiMaterial:2>);
mods.mekanism.Enrichment.removeRecipe(<appliedenergistics2:item.ItemMultiMaterial:2>);
mods.mekanism.Enrichment.addRecipe(<appliedenergistics2:tile.OreQuartz>, <appliedenergistics2:item.ItemMultiMaterial:0> * 5);
mods.mekanism.Enrichment.addRecipe(<appliedenergistics2:tile.OreQuartzCharged>, <appliedenergistics2:item.ItemMultiMaterial:1> * 5);

#Remove generator furnace - machine block recipe
var battery = <IC2:itemBatREDischarged>;
var battery_charged = <IC2:itemBatRE:*>;
var generator = <IC2:blockGenerator:0>;

recipes.remove(generator);
recipes.addShaped(generator, [[null, battery, null], [iron_plate, iron_plate, iron_plate], [null, iron_furnace, null]]);
recipes.addShaped(generator, [[null, battery_charged, null], [iron_plate, iron_plate, iron_plate], [null, iron_furnace, null]]);

#Do the same thing with the solid heat generator
var heat_cond = <IC2:itemRecipePart:5>;

recipes.removeShaped(<IC2:blockHeatGenerator:0>, [[heat_cond], [mac_block], [<minecraft:furnace>]]); #FFS IC2, why you delete both recipes?
recipes.addShaped(<IC2:blockHeatGenerator:0>, [[null, heat_cond, null], [iron_plate, iron_plate, iron_plate], [null, iron_furnace, null]]);

#Nerf Project.Red pipes

var diamond_chipset = <BuildCraft|Silicon:redstoneChipset:3>;
var emerald_chipset = <BuildCraft|Silicon:redstoneChipset:7>;
var advancedlogi_pipe = <ProjRed|Transportation:projectred.transportation.pipe:0>;

recipes.remove(advancedlogi_pipe);
recipes.addShaped(advancedlogi_pipe * 16, [[diamond_chipset, sorter, diamond_chipset], [logi_pipe, <Mekanism:ControlCircuit:2>, logi_pipe], [diamond_chipset, sorter, diamond_chipset]]);

recipes.remove(<ProjRed|Transportation:projectred.transportation.routerutil>);
recipes.addShaped(<ProjRed|Transportation:projectred.transportation.routerutil>, [[null, null, diamond_chipset], [steel_plate, emerald_chipset, steel_plate], [alloy, alloy, alloy]]);

mods.mekanism.Infuser.removeRecipe(<minecraft:mossy_cobblestone>);
mods.mekanism.Infuser.removeRecipe(<Mekanism:EnrichedAlloy>);
mods.mekanism.Infuser.addRecipe("REDSTONE", 10, <IC2:itemPartAlloy>, <Mekanism:EnrichedAlloy>);

recipes.remove(<Mekanism:PartTransmitter:0>);
recipes.addShaped(<Mekanism:PartTransmitter:0> * 8, [[<ThermalFoundation:bucket:4>, electrum, <ThermalFoundation:bucket:4>], [alloy, <IC2:itemDust2>, alloy], [<ThermalFoundation:bucket:4>, electrum, <ThermalFoundation:bucket:4>]]);