// --- Importing Recipes ---

import mods.nei.NEI;
import mods.gregtech.ChemicalReactor;
import mods.gregtech.BlastFurnace;
import mods.gregtech.Electrolyzer;
import mods.gregtech.Assembler;
import mods.gregtech.Canner;
import mods.ic2.Compressor;
import mods.gregtech.ForgeHammer;
import mods.ic2.Extractor;
import mods.ic2.Macerator;
import mods.gregtech.Centrifuge;
import minetweaker.item.IIngredient;
import minetweaker.item.IItemStack;

// --- Variables ---

var GTGearDiamond = <gregtech:gt.metaitem.02:31500>;
var GTGearGold = <gregtech:gt.metaitem.02:31086>;
var plateDiamond = <gregtech:gt.metaitem.01:17500>;
var GTDustElectrumFlux = <gregtech:gt.metaitem.01:2320>;
var itemRedstone = <minecraft:redstone>;
var GTDustElectrum = <gregtech:gt.metaitem.01:2303>;
var GTDustEnderium = <gregtech:gt.metaitem.01:2321>;
var IC2DustTin = <IC2:itemDust:7>;
var GTDustEnderPearl = <gregtech:gt.metaitem.01:2532>;
var AEDustEnder = <appliedenergistics2:item.ItemMultiMaterial:46>;
var GTCrystalFlux = <gregtech:gt.metaitem.01:8517>;
var diamond = <minecraft:diamond>;
var cropHarvester = <IC2:blockMachine3:7>;
var robotArmHV = <gregtech:gt.metaitem.01:32652>;
var circuitEnergyFlow = <gregtech:gt.metaitem.01:32706>;
var pistonElectricHV = <gregtech:gt.metaitem.01:32642>;
var machineHullHV = <gregtech:gt.blockmachines:13>;
var cableElectrum4x = <gregtech:gt.blockmachines:1448>;
var moduleConveyorHV = <gregtech:gt.metaitem.01:32632>;
var sensorHV = <gregtech:gt.metaitem.01:32692>;
var fuelRodUranium = <IC2:reactorUraniumSimple>;
var fuelRodMox = <IC2:reactorMOXSimple>;
var nuclearFuelEnrichedUranium = <IC2:itemUran>;
var nuclearFuelMOX = <IC2:itemMOX>;
var fuelRodEmpty = <IC2:itemFuelRod>;
var circuitAdvanced = <ore:circuitAdvanced>;
var circuitBasic = <ore:circuitBasic>;
var charcoal = <minecraft:coal:1>;
var andesDust = <gregtech:gt.metaitem.01:2868>; 
andesDust.displayName = "Andesite Dust";
var dioriteDust = <gregtech:gt.metaitem.01:2861>;
dioriteDust.displayName = "Diorite Dust";
var GraphiteCell = <gregtech:gt.metaitem.01:30865>;
var CarbonDioxideCell = <gregtech:gt.metaitem.01:30497>;
var TitaniumTetrachlorideCell = <gregtech:gt.metaitem.01:30376>;
TitaniumTetrachlorideCell.displayName = "Titanium Tetrachloride Cell";
game.setLocalization("magnesiumchloride", "Magnesium Chloride");
var MagnesiumChlorideCell = <gregtech:gt.metaitem.01:30377>;
<gregtech:gt.metaitem.01:30377>.displayName = "Magnesium Chloride Cell";
var MagnesiumChlorideDust = <gregtech:gt.metaitem.01:2377>;
<gregtech:gt.metaitem.01:2377>.displayName = "Magnesium Chloride Dust";
<gregtech:gt.metaitem.01:1377>.displayName = "Small Pile of Magnesium Chloride Dust";
<gregtech:gt.metaitem.01:377>.displayName = "Tiny Pile of Magnesium Chloride Dust";
var SodiumDust = <gregtech:gt.metaitem.01:2017>;
var RutileDust = <gregtech:gt.metaitem.01:2375>;
var TitaniumIngot = <gregtech:gt.metaitem.01:11028>;
var SaltDust = <gregtech:gt.metaitem.01:2817>;
var MagnesiumDust = <gregtech:gt.metaitem.01:2018>;


/* ***********************************
	--- Chemical reactor recipes ---
************************************ */

// --- Special alloys ---
ChemicalReactor.addRecipe(GTDustElectrumFlux, itemRedstone * 5, GTDustElectrum, 500);
ChemicalReactor.addRecipe(GTDustEnderium, IC2DustTin * 4, GTDustEnderPearl, 500);
ChemicalReactor.addRecipe(GTDustEnderium, IC2DustTin * 4, AEDustEnder, 500);
ChemicalReactor.addRecipe(GTCrystalFlux, diamond, itemRedstone * 5, 500);

// --- Correcting Kroll process (using graphite cells, as carbon cells do not exist) ---
//OutputStack, OutputFluid, InputStack1, InputStack2, InputFluid, Time in Ticks
ChemicalReactor.addRecipe(CarbonDioxideCell, <liquid:titaniumtetrachloride> * 1000, RutileDust, GraphiteCell, <liquid:chlorine> * 2000, 500);

/* ***************************************
		--- Blast Furnace recipes ---
**************************************** */

BlastFurnace.addRecipe([TitaniumIngot, SaltDust * 4], <liquid:titaniumtetrachloride> * 1000, [SodiumDust * 4], 700, 480, 1700);

/* ***************************************
		--- Electrolyzer recipes ---
**************************************** */

Electrolyzer.addRecipe([MagnesiumDust], <liquid:chlorine> * 2000,  MagnesiumChlorideDust * 2, null, null, [10000, 10000], 40, 30);
//Electrolyzer.addRecipe([RutileDust * , ], <liquid:hydrogen> * , cell * , [10000, 10000], ticktime, energyusage);

/* **************************
	--- Canning Recipes ---
*************************** */

Canner.addRecipe(fuelRodUranium, nuclearFuelEnrichedUranium, fuelRodEmpty, 210, 2);
Canner.addRecipe(fuelRodMox, nuclearFuelMOX, fuelRodEmpty, 210, 2);
Canner.addRecipe(<gregtech:gt.Thoriumcell>, <IC2:itemFuelRod>, <gregtech:gt.metaitem.01:2096>, 200, 40);

/* ***************************
	--- Macerator recipes ---
**************************** */

// --- Chisel diorite ---
Macerator.addRecipe(dioriteDust, <chisel:diorite>);

// --- Chisel andesite ---
Macerator.addRecipe(andesDust, <chisel:andesite>);
Macerator.addRecipe(andesDust, <Botania:stone>);

/* ****************************
	--- Centrifuge recipes ---
***************************** */

// --- Chisel rhyolite ---
Centrifuge.addRecipe([<gregtech:gt.metaitem.01:2848>, <gregtech:gt.metaitem.01:2837> * 3], null, <gregtech:gt.metaitem.01:2875> * 4, null, null, [10000, 10000], 256, 16);

// --- Chisel dacite ---
Centrifuge.addRecipe([<gregtech:gt.metaitem.01:2848>, <gregtech:gt.metaitem.01:2875>], null, <gregtech:gt.metaitem.01:2859> * 2, null, null, [10000, 10000], 400, 16);
// --- Chisel andesite ---
Centrifuge.addRecipe([<gregtech:gt.metaitem.01:2837>, <gregtech:gt.metaitem.01:2859>, <gregtech:gt.metaitem.02:27528>, <gregtech:gt.metaitem.01:3933>], null, andesDust * 3, null, null, [10000, 10000, 500, 600], 200, 16);

// --- Chisel diorite ---
Centrifuge.addRecipe([<gregtech:gt.metaitem.01:2848>, <gregtech:gt.metaitem.01:2837>, <gregtech:gt.metaitem.02:27505>, <gregtech:gt.metaitem.01:3918>], null, dioriteDust * 3, null, null, [10000, 10000, 500, 300], 700, 16);

/* ***********************************
	--- Shaped & Shapeless recipes ---
************************************* */

// --- Small Clay Dust ---
recipes.addShapeless(<gregtech:gt.metaitem.01:1805>, [<ore:craftingToolMortar>, <minecraft:clay_ball>]);

// --- Flour ---
recipes.remove(<Natura:barleyFood:1>);
recipes.remove(<Natura:barleyFood:2>);
recipes.addShapeless(<gregtech:gt.metaitem.01:2881>, [<ore:cropBarley>, <ore:craftingToolMortar>]);

// --- Damascus Steel Dust ---
recipes.addShapeless(<gregtech:gt.metaitem.01:2335> * 3,
[<ore:dustSteel>, <ore:dustCoal>, <ore:dustSilicon>, <ore:dustManganese>, <ore:dustChrome>, <ore:dustMolybdenum>, <ore:dustNickel>, <ore:dustNickel>, <ore:dustNickel>]);

recipes.addShapeless(<gregtech:gt.metaitem.01:2335> * 3,
[<ore:dustSteel>, <ore:dustCoal>, <ore:dustManganese>, <ore:dustManganese>, <ore:dustSilicon>, <ore:dustChrome>, <ore:dustChrome>, <ore:dustVanadium>]);

// --- Shadow Iron Dust ---
recipes.addShapeless(<gregtech:gt.metaitem.01:2336> * 3, 
[<ore:dustIron>, <ore:dustThaumium>, <ore:dustThaumium>, <ore:dustThaumium>]);

// --- Osmiridium Dust ---
recipes.addShapeless(<gregtech:gt.metaitem.01:2317> * 3, 
[<ore:dustOsmium>, <ore:dustIridium>, <ore:dustIridium>, <ore:dustIridium>]);

// --- UV Machine Casing ---
recipes.addShaped(<gregtech:gt.blockcasings:8>, [
[<ore:plateAlloyIridium>, <ore:plateAlloyIridium>, <ore:plateAlloyIridium>],
[<ore:plateAlloyIridium>, <ore:craftingToolWrench>, <ore:plateAlloyIridium>],
[<ore:plateAlloyIridium>, <ore:plateAlloyIridium>, <ore:plateAlloyIridium>]]);

/* ******************************
	--- Forge Hammer Recipes ---
****************************** */

ForgeHammer.addRecipe(<gregtech:gt.metaitem.02:22874>, <gregtech:gt.metaitem.01:23874> * 2, 20, 16);


/* ****************************
	--- Assembler Recipes ---
***************************** */

// --- Low Voltage Transformer ---
Assembler.addRecipe(<gregtech:gt.blockmachines:21>, <IC2:blockElectric:3>, <gregtech:gt.blockmachines:1246> * 2, 300, 32);

// --- Medium Voltage Transformer ---
Assembler.addRecipe(<gregtech:gt.blockmachines:22>, <IC2:blockElectric:4>, <gregtech:gt.blockmachines:1366> * 2, 250, 128);

// --- High Voltage Transformer ---
Assembler.addRecipe(<gregtech:gt.blockmachines:23>, <IC2:blockElectric:5>, <gregtech:gt.blockmachines:1426> * 2, 200, 512);

// --- Extreme Transformer ---
Assembler.addRecipe(<gregtech:gt.blockmachines:24>, <IC2:blockElectric:6>, <gregtech:gt.blockmachines:1587> * 2, 100, 2048);

// --- Torches from charcoal ---
//Assembler.addRecipe(output, input1, input2, durationTicks, euPerTick);
Assembler.addRecipe(<minecraft:torch> * 6, charcoal, <minecraft:stick>, 400, 1);

// --- Diamond Gear ---
Assembler.addRecipe(GTGearDiamond, GTGearGold, plateDiamond, 1600, 2);

/* *******************************
		--- End of Script ---
******************************** */