[MineTweaker-Scripts & Mod-Configs] Let's Greg other mods!

DreamMasterXXL · Feb 21st 2015

Quote from agosto64

Fast and effective! Thank´s Dream!

Requia · Feb 21st 2015

Do you know if there's a way to edit the ore byproduct list instead of going through every machine independently?

Trying to make uranium (and uranium like ores) make U235 as byproduct instead of plutonium. The number of mods greg changed recipes of is staggering though.

DreamMasterXXL · Feb 21st 2015

@ Requia

With minetweaker i think there is no way to do things like that. It sound interesting to changing by products. May Be asking Greg because i dont know how to changing it.
Sorry.

btw. If you find it out post it here. Thanks

Requia · Feb 21st 2015

Oooh, or a way to add biogas to his gas turbines (with efficiency loss of course).

Usernm · Feb 22nd 2015

Quote from Requia

Oooh, or a way to add biogas to his gas turbines (with efficiency loss of course).

Minetweaker 3 wiki

Code

import mods.gregtech.Fuels;




Fuels.addGasTurbineFuel(output, input, euPerMillibucket);

If this not works - have no idea how to do that.

Requia · Feb 22nd 2015

I noticed implosion compressor recipes going through the galacticraft script.

As of GT5.05.06, the *only* thing the implosion compressor is actually required for is iridium reinforced plates, which in turn is only for the quantum suit and nano saber (the gem recipes are in there, but unnecessary, since the sifter can get the gems from purified crushed ore, and you don't need the gems for any gregtech recipes). The industrial diamond and gem plates are all normal compressor. Should probably be pulled, since GT5 itself no longer requires the machine prior to the absolute end of the infrastructure ladder. Will do this myself and submit pull requests if people approve, not gonna put in the work if everyone is against me.

It also might be prudent to fork the whole thing soon, since I'm sure other changes will be warranted as GT6 comes online, and GT5 worlds can't be updated.

nister · Feb 24th 2015

Advanced generators config need update.

DreamMasterXXL · Feb 24th 2015

nister
I don't use the mod and i not make this Minetweaker Scripts. You can send me a pull Request on Github or send me the code via Pm or post it here in the Thread.
Only the cfg file need a update or the whole Minetweaker script ?

nister · Feb 24th 2015

This config is for old version, it crash.
Script also does not work (this older one works for me).

I will maybe fix but im very busy so i dont promise.

DreamMasterXXL · Feb 24th 2015

nister

Thanks for report. No rush with the script. If I using this mod some day i look inside.

DreamMasterXXL · Feb 26th 2015

Making Minecraft a little bit more magical.

Brewing Stand, Beacon, Enderchest and Enchantment Table now have a Thaumcraft Infusion/Arcane Recipes:

Code

// --- Ender Chest
recipes.remove(EnderChest);
// --- Beacon
recipes.remove(Beacon);
// --- Enchantment Table
recipes.remove(EnchantingTable);
//Brewing Stand
recipes.remove(<minecraft:brewing_stand>);




//Enchanting Table Infusion
mods.thaumcraft.Research.addResearch("ENCHANTINGTABLE", "ARTIFICE", "praecantatio 200, fabrico 200, cognitio 100, potentia 200", 10, 10, 12, <minecraft:enchanting_table>);
game.setLocalization("en_US", "tc.research_name.ENCHANTINGTABLE", "Enchanting Table");
game.setLocalization("en_US", "tc.research_text.ENCHANTINGTABLE", "[MC] Oh, it's more magical than a Table!");
mods.thaumcraft.Research.addPrereq("ENCHANTINGTABLE", "INFUSION", false);
mods.thaumcraft.Research.setConcealed("ENCHANTINGTABLE", true);
mods.thaumcraft.Research.addPage("ENCHANTINGTABLE", "Minecraft.research_page.ENCHANTINGTABLE");
game.setLocalization("en_US", "Minecraft.research_page.ENCHANTINGTABLE", "An enchantment table is a block that allows players to spend their experience point levels to enchant tools, books and armor. The enchanting table's main purpose is to enchant items. Bookshelves surrounding the table, with a block of air in between, will increase the maximum enchantment level. The table will enchant all tools and armor except the hoe, shears, flint and steel, lead and horse armor. The hoe and shears cannot be enchanted by the enchantment table and require an anvil and an appropriate enchanted book.");
mods.thaumcraft.Infusion.addRecipe("ENCHANTINGTABLE", <minecraft:obsidian>, [<minecraft:bookshelf>, <Thaumcraft:ItemResource:1>, <minecraft:diamond_block>, <Thaumcraft:ItemResource>, <IC2:itemDensePlates:7>, <minecraft:bookshelf>, <Thaumcraft:ItemResource:1>, <minecraft:diamond_block>, <Thaumcraft:ItemResource>, <IC2:itemDensePlates:7>], "praecantatio 120, fabrico 100, cognitio 120, potentia 80", <minecraft:enchanting_table>, 5);
mods.thaumcraft.Research.addInfusionPage("ENCHANTINGTABLE", <minecraft:enchanting_table>);
mods.thaumcraft.Warp.addToResearch("ENCHANTINGTABLE", 2);




//Ender Chest Arcane
mods.thaumcraft.Research.addResearch("ENDERCHEST", "ARTIFICE", "praecantatio 200, iter 200, vacuos 100, tenebrae 100, terra 80, ignis 80, ", 12, 12, 12, <minecraft:ender_chest>);
game.setLocalization("en_US", "tc.research_name.ENDERCHEST", "Ender Chest");
game.setLocalization("en_US", "tc.research_text.ENDERCHEST", "[MC] Oh, it's more magical than a Chest!");
mods.thaumcraft.Research.addPrereq("ENDERCHEST", "ENCHANTINGTABLE", false);
mods.thaumcraft.Research.setConcealed("ENDERCHEST", true);
mods.thaumcraft.Research.addPage("ENDERCHEST", "Minecraft.research_page.ENDERCHEST");
game.setLocalization("en_US", "Minecraft.research_page.ENDERCHEST", "The Ender Chest is a block that allows the player to store 27 items much like a wooden chest however, if two Ender Chests are placed down in different places, the items inside chest A will be in chest B. If the items are taken from either chest, both of the chest will not have that item. While on SMP, players will not share the same storage. This can be used to prevent players form stealing more valuable items, as they cannot access the same a items. This also means two players can store items in the same ender chest.");
mods.thaumcraft.Arcane.addShaped("ENDERCHEST", <minecraft:ender_chest>, "aer 100, aqua 100, ignis 100, terra 100", [
[<gregtech:gt.metaitem.01:17506>, <gregtech:gt.metaitem.01:22321>, <gregtech:gt.metaitem.01:17506>],
[<gregtech:gt.metaitem.01:22321>, ObsidianChest, <gregtech:gt.metaitem.01:22321>],
[<gregtech:gt.metaitem.01:17506>, <gregtech:gt.metaitem.01:22321>, <gregtech:gt.metaitem.01:17506>]]);
mods.thaumcraft.Research.addArcanePage("ENDERCHEST", <minecraft:ender_chest>);
mods.thaumcraft.Warp.addToResearch("ENDERCHEST", 2);




//Brewing Stand Infusion
mods.thaumcraft.Research.addResearch("BREWINGSTAND", "ARTIFICE", "praecantatio 200, fabrico 100, cognitio 100, perditio 100, ignis 100, terra 100, aqua 100", 8, 12, 12, <minecraft:brewing_stand>);
game.setLocalization("en_US", "tc.research_name.BREWINGSTAND", "Brewing Stand");
game.setLocalization("en_US", "tc.research_text.BREWINGSTAND", "[MC] Oh, it's more magical than a Cauldron!");
mods.thaumcraft.Research.addPrereq("BREWINGSTAND", "ENCHANTINGTABLE", false);
mods.thaumcraft.Research.setConcealed("BREWINGSTAND", true);
mods.thaumcraft.Research.addPage("BREWINGSTAND", "brewingstand.research_page.BREWINGSTAND.1");
game.setLocalization("en_US", "brewingstand.research_page.BREWINGSTAND.1", "Brewing (or Alchemy) is the process of creating potions and splash potions by adding various ingredients to water bottles in a brewing stand. By placing bottles in the lower three slots of the brewing interface and an ingredient in the upper slot, you can distill the ingredient into the bottles and brew potions which may be consumed to grant an effect to the player. Every potion starts with a water bottle, made by filling a glass bottle at a water source or filled cauldron. The next step is to add a primary ingredient to create a base potion, which is usually Nether Wart, which creates an awkward potion and has no effects.");
mods.thaumcraft.Research.addPage("BREWINGSTAND", "brewingstand.research_page.BREWINGSTAND.2");
game.setLocalization("en_US", "brewingstand.research_page.BREWINGSTAND.2", "By brewing a second ingredient into a base potion in the same manner, you can create a potion with a working effect. A third ingredient may be added to make the effect more intense or last longer, or turn the effect harmful. Finally, gunpowder can be added to a potion at any stage to convert it to a splash potion, which can be thrown (or fired using a dispenser) to disperse its effect in a radius. Each brewing step takes 20 seconds. Brewing can create very useful and lifesaving items. A good number of them are useful in combat by aiding the player or weakening enemies while others can save the player's life if used quickly, like Fire Resistance or Healing.");
mods.thaumcraft.Research.addPage("BREWINGSTAND", "Minecraft.research_page.BREWINGSTAND.3");
game.setLocalization("en_US", "Minecraft.research_page.BREWINGSTAND.3", "Gathering the Blaze Rods and Nether Wart necessary for brewing can prove challenging, but once they are set up, most potion ingredients are fairly plentiful and brewing will be a rewarding task.");
mods.thaumcraft.Infusion.addRecipe("BREWINGSTAND", <minecraft:cauldron>, [<gregtech:gt.metaitem.02:22801>, <minecraft:glass_bottle>, <gregtech:gt.metaitem.01:23311>, <minecraft:glass_bottle>, <gregtech:gt.metaitem.01:23311>, <minecraft:glass_bottle>, <gregtech:gt.metaitem.02:22801>, <gregtech:gt.metaitem.01:28311>, <gregtech:gt.metaitem.01:27047>, <gregtech:gt.metaitem.01:28311>, <gregtech:gt.metaitem.01:27047>, <gregtech:gt.metaitem.01:28311>], "praecantatio 120, fabrico 80, cognitio 80, perditio 80, ignis 80, terra 80, aqua 80", <minecraft:brewing_stand>, 5);
mods.thaumcraft.Research.addInfusionPage("BREWINGSTAND", <minecraft:brewing_stand>);
mods.thaumcraft.Warp.addToResearch("BREWINGSTAND", 2);




//Beacon Infusion
mods.thaumcraft.Research.addResearch("BEACON", "ARTIFICE", "alienis 200, praecantatio 200, auram 100, fames 400", 10, 12, 12, <minecraft:beacon>);
game.setLocalization("en_US", "tc.research_name.BEACON", "Beacon");
game.setLocalization("en_US", "tc.research_text.BEACON", "[MC] Oh, it's more magical than a Diamond Block!");
mods.thaumcraft.Research.addPrereq("BEACON", "ENCHANTINGTABLE", false);
mods.thaumcraft.Research.setConcealed("BEACON", true);
mods.thaumcraft.Research.addPage("BEACON", "Minecraft.research_page.BEACON");
game.setLocalization("en_US", "Minecraft.research_page.BEACON", "A beacon is a unique block that projects a light beam skyward and can provide status effects to players in the vicinity. Beacon blocks can function as light sources, emitting a light level 15. Like other light sources, they will melt snow and ice. When activated, beacon blocks provide two unique functions: An aesthetic landmark beam reaching into the sky, which can be visible from far away. Powers, which give players status effects within a certain range.");
mods.thaumcraft.Infusion.addRecipe("BEACON", <ForbiddenMagic:StarBlock>, [<minecraft:glass>, <gregtech:gt.metaitem.01:17804>, <gregtech:gt.metaitem.01:24500>, <minecraft:glass>, <gregtech:gt.metaitem.01:17804>, <gregtech:gt.metaitem.01:24500>, <minecraft:glass>, <gregtech:gt.metaitem.01:17804>, <gregtech:gt.metaitem.01:24500>, <minecraft:glass>, <gregtech:gt.metaitem.01:17804>, <gregtech:gt.metaitem.01:24500>], "praecantatio 120, alienis 100, lux 120, ordo 80, ignis 80, terra 80", <minecraft:beacon>, 6);
mods.thaumcraft.Research.addInfusionPage("BEACON", <minecraft:beacon>);
mods.thaumcraft.Warp.addToResearch("BEACON", 2);

Display More

DreamMasterXXL · Feb 26th 2015

Changing Forestry Alveary Recipes be craftable in the Forestry Carpenter:

Code

//Alveary
recipes.remove(<Forestry:alveary>);
//Swarmer
recipes.remove(<Forestry:alveary:2>);
//Alveary Fan
recipes.remove(<Forestry:alveary:3>);
//Alveary Heater
recipes.remove(<Forestry:alveary:4>);
//Alveary Hygroregulator
recipes.remove(<Forestry:alveary:5>);
//Alveary Stabiliser
recipes.remove(<Forestry:alveary:6>);
//Alveary Sieve
recipes.remove(<Forestry:alveary:7>);




//Alveary
Assembler.addRecipe(<Forestry:alveary>, <Forestry:impregnatedCasing>, <Forestry:craftingMaterial:6> * 8, 1200, 64);




//Alveary Fan
mods.forestry.Carpenter.addRecipe(1200, <liquid:honey> * 5000,
[<Forestry:thermionicTubes:11>, <dreamcraft:item.SteelBars>, <Forestry:thermionicTubes:11>,
<dreamcraft:item.SteelBars>, <GalacticraftCore:item.airFan>, <dreamcraft:item.SteelBars>,
<Forestry:thermionicTubes:11>, <gregtech:gt.metaitem.01:32600>, <Forestry:thermionicTubes:11>],
<Forestry:alveary:*>, <Forestry:alveary:3>);
//Alveary Heater
mods.forestry.Carpenter.addRecipe(1200, <liquid:honey> * 5000,
[<Forestry:thermionicTubes:7>, <dreamcraft:item.SteelBars>, <Forestry:thermionicTubes:7>,
<IC2:itemRecipePart>, <IC2:itemRecipePart>, <IC2:itemRecipePart>,
<Forestry:thermionicTubes:7>, <gregtech:gt.metaitem.01:32600>, <Forestry:thermionicTubes:7>],
<Forestry:alveary:*>, <Forestry:alveary:4>);
//Alveary Hygroregulator
mods.forestry.Carpenter.addRecipe(1200, <liquid:honey> * 5000,
[<Forestry:thermionicTubes:6>, <OpenBlocks:bigbutton>, <Forestry:thermionicTubes:6>,
<BuildCraft|Factory:tankBlock>, <gregtech:gt.blockmachines:5142>, <BuildCraft|Factory:tankBlock>,
<Forestry:thermionicTubes:6>, <gregtech:gt.metaitem.01:17308>, <Forestry:thermionicTubes:6>],
<Forestry:alveary:*>, <Forestry:alveary:5>);
//Alveary Stabiliser
mods.forestry.Carpenter.addRecipe(1200, <liquid:honey> * 5000,
[<Forestry:thermionicTubes:8>, <gregtech:gt.metaitem.01:17517>, <Forestry:thermionicTubes:8>,
<gregtech:gt.metaitem.01:32729>, <IC2:blockAlloy>, <gregtech:gt.metaitem.01:32729>,
<Forestry:thermionicTubes:8>, <gregtech:gt.metaitem.01:17517>, <Forestry:thermionicTubes:8>],
<Forestry:alveary:*>, <Forestry:alveary:6>);
//Alveary Sieve
mods.forestry.Carpenter.addRecipe(1200, <liquid:honey> * 5000,
[<Forestry:thermionicTubes:9>, <Forestry:craftingMaterial:3>, <Forestry:thermionicTubes:9>,
<Forestry:craftingMaterial:3>, <Forestry:pollenFertile>, <Forestry:craftingMaterial:3>,
<Forestry:thermionicTubes:9>, <Forestry:craftingMaterial:3>, <Forestry:thermionicTubes:9>],
<Forestry:alveary:*>, <Forestry:alveary:7>);

Display More

DreamMasterXXL · Feb 26th 2015

Changing recipes for the apiary /chest and Bee House

Code

//Bee House
recipes.remove(<Forestry:apiculture:2>);
//Apiary
recipes.remove(<Forestry:apiculture>);
//Apiarys Chest
recipes.remove(<Forestry:apiculture:1>);




//Bee House
recipes.addShaped(<Forestry:apiculture:2>, [
[<ore:slabWood>, <ore:slabWood>, <ore:slabWood>],
[<Forestry:frameUntreated>, <Forestry:sturdyMachine>, <Forestry:frameUntreated>],
[<ore:beeComb>, <ore:slabWood>, <ore:beeComb>]]);




//Apiary
mods.forestry.Carpenter.addRecipe(800, <liquid:seedoil> * 1000,
[<gregtech:gt.metaitem.01:27809>, <minecraft:wooden_slab:*>, <gregtech:gt.metaitem.01:27809>,
<Forestry:frameImpregnated>, <Forestry:beeCombs:*>, <Forestry:frameImpregnated>,
<minecraft:fence>, <minecraft:wooden_slab:*>, <minecraft:fence>],
<Forestry:apiculture:2>, <Forestry:apiculture>);




//Apiarys Chest
mods.forestry.Carpenter.addRecipe(600, <liquid:honey> * 500,
[<Forestry:beeCombs:*>, <Forestry:beeCombs:*>, <Forestry:beeCombs:*>,
<Forestry:frameImpregnated>, <Forestry:frameImpregnated>, <Forestry:frameImpregnated>,
<Forestry:frameImpregnated>, <gregtech:gt.metaitem.01:27809>, <Forestry:frameImpregnated>],
<minecraft:chest>, <Forestry:apiculture:1>);

Display More

DreamMasterXXL · Feb 26th 2015

Now the red,yellow and green heart and there canisters are available via Thaumcraft infusion /arcane.

Code

// --- Red Heart
recipes.remove(<TConstruct:heartCanister:1>);
// --- Red Heart Canister
recipes.remove(<TConstruct:heartCanister:2>);
// --- Yellow Heart Canister
recipes.remove(<TConstruct:heartCanister:4>);




// --- Red Heart
mods.thaumcraft.Research.addResearch("REDHEART", "ARTIFICE", "ignis 100, praecantatio 100, vacuos 100, perditio 100", 8, 4, 12, <TConstruct:heartCanister:1>);
game.setLocalization("en_US", "tc.research_name.REDHEART", "Red Heart");
game.setLocalization("en_US", "tc.research_text.REDHEART", "[TC] 10 Hearts are not enough.");
mods.thaumcraft.Research.addPrereq("REDHEART", "RUNICAUGMENTATION", false);
mods.thaumcraft.Research.setConcealed("REDHEART", true);
mods.thaumcraft.Research.setRound("REDHEART", true);
mods.thaumcraft.Research.addPage("REDHEART", "TConstruct.research_page.REDHEART.1");
mods.thaumcraft.Research.addPage("REDHEART", "TConstruct.research_page.REDHEART.2");
game.setLocalization("en_US", "TConstruct.research_page.REDHEART.1", "The Miniature Red Heart is an item from Tinkers' Construct. It is extremely rare and has very little uses, as it is only used to craft the Heart Canister.It is dropped randomly by hostile mobs or crafting via Infusion. The drop rate is 0.2% from regular hostile mobs. The heart may drop anytime a mob dies, the kill does not have to be caused by a player.Its primary use is in crafting the Red Heart Canister, but it can also be eaten to restore 10 life.<BR> The Red Heart Canister which increases the amount of hearts that the player has. To have an effect the canisters must be equipped in the Armor Tab, in the slot on the");
game.setLocalization("en_US", "TConstruct.research_page.REDHEART.2", "right with the symbol that looks like the red heart canister. Up to 10 can be stacked in this slot to allow for a total of 10 extra hearts (or 20 extra health points). These will not appear above the regular health bar like from the Absorption effect, instead once the health bar is full the red hearts will gradually be replaced by orange hearts.");
mods.thaumcraft.Infusion.addRecipe("REDHEART", <minecraft:golden_apple>, [<TConstruct:jerky:6>, <minecraft:apple>, <TConstruct:jerky:7>, <TConstruct:materials:8>, <TConstruct:jerky>, <TConstruct:jerky:1>, <TConstruct:jerky:2>, <TConstruct:jerky:3>, <TConstruct:jerky:4>, <TConstruct:jerky:5>], "exanimis 25, ignis 35, lucrum 35, sano 50, praecantatio 50", <TConstruct:heartCanister:1>, 3);
mods.thaumcraft.Research.addInfusionPage("REDHEART", <TConstruct:heartCanister:1>);
mods.thaumcraft.Arcane.addShaped("REDHEART", <TConstruct:heartCanister:2>, "aer 50, aqua 50, ignis 50, terra 50, ordo 50, perditio 50", [
[<TConstruct:materials:8>, <TConstruct:heartCanister>, null],
[<minecraft:golden_apple>, <TConstruct:heartCanister:1>, null],
[null, null, null]]);
mods.thaumcraft.Research.addArcanePage("REDHEART", <TConstruct:heartCanister:2>);
mods.thaumcraft.Warp.addToResearch("REDHEART", 1);




// --- Yellow Heart
mods.thaumcraft.Research.addResearch("YELLOWHEART", "ARTIFICE", "ignis 100, praecantatio 100, vacuos 100, perditio 100", 9, 3, 12, <TConstruct:heartCanister:3> );
game.setLocalization("en_US", "tc.research_name.YELLOWHEART", "Yellow Heart");
game.setLocalization("en_US", "tc.research_text.YELLOWHEART", "[TC] 20 Hearts are not enough.");
mods.thaumcraft.Research.addPrereq("YELLOWHEART", "REDHEART", false);
mods.thaumcraft.Research.setConcealed("YELLOWHEART", true);
mods.thaumcraft.Research.setRound("YELLOWHEART", true);
mods.thaumcraft.Research.addPage("YELLOWHEART", "TConstruct.research_page.YELLOWHEART.1");
mods.thaumcraft.Research.addPage("YELLOWHEART", "TConstruct.research_page.YELLOWHEART.2");
game.setLocalization("en_US", "TConstruct.research_page.YELLOWHEART.1", "The Miniature Yellow Heart is an item from Tinkers' Construct. It can be obtained by killing Boss mobs such as the Wither or King Slime, as well as from killing any Boss Monsters in the Twilight like the Naga, the Lich or the Hydra. Its primary use is in crafting the Yellow Heart Canister, but it can also be eaten to restore 20 life.<BR> The Yellow Heart Canister which increases the amount of hearts that the player has. To have an effect the canisters must be equipped in the Armor Tab, in the slot on the right with the symbol that looks like the yellow heart canister");
game.setLocalization("en_US", "TConstruct.research_page.YELLOWHEART.2", "Up to 10 can be stacked in this slot to allow for a total of 10 extra hearts (or 20 extra health points). These will not appear above the regular health bar like from the Absorption effect, instead once the health bar is full with orange hearts it will gradually be replaced by yellow hearts.");
mods.thaumcraft.Infusion.addRecipe("YELLOWHEART", <minecraft:golden_apple:1>, [<TConstruct:heartCanister:1>, <TConstruct:materials:8>, <TConstruct:heartCanister:1>, <TConstruct:materials:8>, <TConstruct:heartCanister:1>, <TConstruct:materials:8>, <TConstruct:heartCanister:1>, <TConstruct:materials:8>, <TConstruct:heartCanister:1>, <TConstruct:materials:8>], "exanimis 50, ignis 75, lucrum 75, sano 100, praecantatio 100", <TConstruct:heartCanister:3>, 3);
mods.thaumcraft.Research.addInfusionPage("YELLOWHEART", <TConstruct:heartCanister:3>);
mods.thaumcraft.Arcane.addShaped("YELLOWHEART", <TConstruct:heartCanister:4>, "aer 100, aqua 100, ignis 100, terra 100, ordo 100, perditio 100", [
[<TConstruct:materials:8>, <TConstruct:heartCanister>, <TConstruct:materials:8>],
[<minecraft:golden_apple:1>, <TConstruct:heartCanister:3>, <minecraft:golden_apple:1>],
[null, null, null]]);
mods.thaumcraft.Research.addArcanePage("YELLOWHEART", <TConstruct:heartCanister:4>);
mods.thaumcraft.Warp.addToResearch("YELLOWHEART", 2);




// --- Green Heart
mods.thaumcraft.Research.addResearch("GREENHEART", "ARTIFICE", "ignis 100, praecantatio 100, vacuos 100, perditio 100", 9, 1, 12, <TConstruct:heartCanister:5>);
game.setLocalization("en_US", "tc.research_name.GREENHEART", "Green Heart");
game.setLocalization("en_US", "tc.research_text.GREENHEART", "[TC] 30 Hearts are not enough.");
mods.thaumcraft.Research.addPrereq("GREENHEART", "YELLOWHEART", false);
mods.thaumcraft.Research.setConcealed("GREENHEART", true);
mods.thaumcraft.Research.setRound("GREENHEART", true);
mods.thaumcraft.Research.addPage("GREENHEART", "TConstruct.research_page.GREENHEART.1");
mods.thaumcraft.Research.addPage("GREENHEART", "TConstruct.research_page.GREENHEART.2");
game.setLocalization("en_US", "TConstruct.research_page.GREENHEART.1", "The Miniature Green Heart is an item from Tinkers' Construct. It can be made via Infusion. Its primary use is in crafting the Geen Heart Canister, but it can also be eaten to restore 30 life. <BR> The Green Heart Canister which increases the amount of hearts that the player has. To have an effect the canisters must be equipped in the Armor Tab, in the slot on the right with the symbol that looks like the green heart canister. Up to 10 can be stacked in this slot to allow for a total of 10 extra hearts (or 20 extra health points).");
game.setLocalization("en_US", "TConstruct.research_page.GREENHEART.2", "These will not appear above the regular health bar like from the Absorption effect, instead once the health bar is full with yellow hearts and will gradually be replaced by green hearts. On top of the Yellow Heart Canisters, a maximum of 10 Red Heart Canisters and 10 Yellow Heart Canisters and 10 green Heart Canisters can be equipped for an additional 10 and 20 health points. This brings maximum health up to 40 hearts (or 80 health points)");
mods.thaumcraft.Infusion.addRecipe("GREENHEART", <TConstruct:diamondApple>, [<TConstruct:heartCanister:3>, <TConstruct:materials:8>, <TConstruct:heartCanister:3>, <TConstruct:materials:8>, <TConstruct:heartCanister:3>, <TConstruct:materials:8>, <TConstruct:heartCanister:3>, <TConstruct:materials:8>, <TConstruct:heartCanister:3>, <TConstruct:materials:8>], "exanimis 100, ignis 150, lucrum 150, sano 200, praecantatio 200", <TConstruct:heartCanister:5>, 3);
mods.thaumcraft.Research.addInfusionPage("GREENHEART", <TConstruct:heartCanister:5>);
mods.thaumcraft.Arcane.addShaped("GREENHEART", <TConstruct:heartCanister:6>, "aer 200, aqua 200, ignis 200, terra 200, ordo 200, perditio 200", [
[<TConstruct:materials:8>, <TConstruct:heartCanister>, <TConstruct:materials:8>],
[<TConstruct:diamondApple>, <TConstruct:heartCanister:5>, <TConstruct:diamondApple>],
[<TConstruct:materials:8>, <TConstruct:diamondApple>, <TConstruct:materials:8>]]);
mods.thaumcraft.Research.addArcanePage("GREENHEART", <TConstruct:heartCanister:6>);
mods.thaumcraft.Warp.addToResearch("GREENHEART", 3);

Display More

DreamMasterXXL · Feb 26th 2015

Added now Lava Crystal, Ball of Moss, Silky Jewel and Necrotic Bone to Thaumcraft Infusion /Crucible:

Code

// --- Ball Of Moss
recipes.remove(BallOfMoss);
// --- Silky Cloth
recipes.remove(SilkyCloth);
// --- Silky Jewel
recipes.remove(SilkyJewel);
// --- Lava Crystal
recipes.remove(<TConstruct:materials:7>);




// --- Ball of Moss
mods.thaumcraft.Research.addResearch("BALLOFMOSS", "ARTIFICE", "sano 100, terra 100, instrumentum 100", 13, 6, 12, <TConstruct:materials:6>);
game.setLocalization("en_US", "tc.research_name.BALLOFMOSS", "Ball of Moss");
game.setLocalization("en_US", "tc.research_text.BALLOFMOSS", "[TC] Your Tools repair itselfs.");
mods.thaumcraft.Research.addPrereq("BALLOFMOSS", "SILKYCRYSTAL", false);
mods.thaumcraft.Research.setConcealed("BALLOFMOSS", true);
mods.thaumcraft.Research.setRound("BALLOFMOSS", true);
mods.thaumcraft.Research.addPage("BALLOFMOSS", "TConstruct.research_page.BALLOFMOSS");
game.setLocalization("en_US", "TConstruct.research_page.BALLOFMOSS", "The Ball of Moss for Tinkers Construct Tools.<BR> Attaching moss to a tool infuses it with life. The tool appers to be capable of regenerating wear and tear.<BR>Effects:<BR> The tool slowly repair itself.<BR>Sunlight speeds up the process.");
mods.thaumcraft.Infusion.addRecipe("BALLOFMOSS", <Thaumcraft:ItemResource:15>, [<gregtech:gt.metaitem.01:2542>, <TwilightForest:tile.TFPlant:3>, <BiomesOPlenty:moss>, <gregtech:gt.metaitem.01:2542>, <TwilightForest:tile.TFPlant:3>, <BiomesOPlenty:moss>, <gregtech:gt.metaitem.01:2542>, <TwilightForest:tile.TFPlant:3>, <BiomesOPlenty:moss>, <gregtech:gt.metaitem.01:2542>, <TwilightForest:tile.TFPlant:3>, <BiomesOPlenty:moss>], "sano 30, terra 25, instrumentum 35", <TConstruct:materials:6>, 5);
mods.thaumcraft.Research.addInfusionPage("BALLOFMOSS", <TConstruct:materials:6>);
mods.thaumcraft.Warp.addToResearch("BALLOFMOSS", 2);




// --- Necrotic Bone
mods.thaumcraft.Research.addResearch("NECROTICBONE", "ALCHEMY", "exanimis 100, mortuus 100, spiritus 100, venenum 100", -7, -1, 1, <TConstruct:materials:8>);
game.setLocalization("en_US", "tc.research_name.NECROTICBONE", "Necrotic Bone");
game.setLocalization("en_US", "tc.research_text.NECROTICBONE", "[TC] Evil way to make Wither Skeleton Bones.");
mods.thaumcraft.Research.addPrereq("NECROTICBONE", "ENTROPICPROCESSING", false);
mods.thaumcraft.Research.setConcealed("NECROTICBONE", true);
mods.thaumcraft.Research.setRound("NECROTICBONE", true);
mods.thaumcraft.Research.addPage("NECROTICBONE", "TConstruct.research_page.NECROTICBONE");
game.setLocalization("en_US", "TConstruct.research_page.NECROTICBONE", "The Necrotic Bone is a special drop gained by killing Wither Skeletons, and can be rarely found in dungeon chests. Now you find a evil way to make it out of Skeleton Bones. Currently, the only use for the Necrotic bone is used to craft a Heart Canister and add a modifier to weapons.");
mods.thaumcraft.Crucible.addRecipe("NECROTICBONE", <TConstruct:materials:8>, <minecraft:bone>, "exanimis 20, mortuus 30, infernus 20, spiritus 20, venenum 20, corpus 5");
mods.thaumcraft.Research.addCruciblePage("NECROTICBONE", <TConstruct:materials:8>);
mods.thaumcraft.Warp.addToResearch("NECROTICBONE", 1);




// --- Silky Cloth and Jewel
mods.thaumcraft.Research.addResearch("SILKYCRYSTAL", "ARTIFICE", "pannus 100, lucrum 100, instrumentum 100, aer 100, praecantatio 100", 13, 8, 12, <TConstruct:materials:26>);
game.setLocalization("en_US", "tc.research_name.SILKYCRYSTAL", "Silky Jevel");
game.setLocalization("en_US", "tc.research_text.SILKYCRYSTAL", "[TC] Silky magical.");
mods.thaumcraft.Research.addPrereq("SILKYCRYSTAL", "LAVACRYSTAL", false);
mods.thaumcraft.Research.setConcealed("SILKYCRYSTAL", true);
mods.thaumcraft.Research.setRound("SILKYCRYSTAL", true);
mods.thaumcraft.Research.addPage("SILKYCRYSTAL", "TConstruct.research_page.SILKYCRYSTAL");
game.setLocalization("en_US", "TConstruct.research_page.SILKYCRYSTAL", "Silky Cloth is a manufactured item and is a component of the Silky Jewel.<BR><BR>The Silky Jewel is a manufactured item, used to simulate the Silk Touch enchantment in TC tools.");
mods.thaumcraft.Arcane.addShaped("SILKYCRYSTAL", <TConstruct:materials:25>, "aer 30, aqua 25, ignis 15, terra 15, ordo 10, perditio 10", [
[String, <ore:foilGold>, String],
[<ore:foilGold>, String, <ore:foilGold>],
[String, <ore:foilGold>, String]]);
mods.thaumcraft.Research.addArcanePage("SILKYCRYSTAL", <TConstruct:materials:25>);
mods.thaumcraft.Infusion.addRecipe("SILKYCRYSTAL", <minecraft:diamond_block>, [<TConstruct:materials:25>, <TConstruct:materials:25>, <Thaumcraft:ItemShard>, <TConstruct:materials:25>, <TConstruct:materials:25>, <Thaumcraft:ItemShard:3>, <TConstruct:materials:25>, <TConstruct:materials:25>, <Thaumcraft:ItemShard:4>], "ignis 20, terra 20, ordo 35, praecantatio 35, vitreus 20", <TConstruct:materials:26>, 4);
mods.thaumcraft.Research.addInfusionPage("SILKYCRYSTAL", <TConstruct:materials:26>);
mods.thaumcraft.Warp.addToResearch("SILKYCRYSTAL", 1);




// --- Lava Crystal
mods.thaumcraft.Research.addResearch("LAVACRYSTAL", "ARTIFICE", "ignis 100, praecantatio 100, vacuos 100, perditio 100", 12, 9, 12, <TConstruct:materials:7>);
game.setLocalization("en_US", "tc.research_name.LAVACRYSTAL", "Lava Crystal");
game.setLocalization("en_US", "tc.research_text.LAVACRYSTAL", "[TC] Fiery magical.");
mods.thaumcraft.Research.addPrereq("LAVACRYSTAL", "ENCHANTINGTABLE", false);
mods.thaumcraft.Research.setConcealed("LAVACRYSTAL", true);
mods.thaumcraft.Research.setRound("LAVACRYSTAL", true);
mods.thaumcraft.Research.addPage("LAVACRYSTAL", "TConstruct.research_page.LAVACRYSTAL");
game.setLocalization("en_US", "TConstruct.research_page.LAVACRYSTAL", "A Lava Crystal is a modifier both for tools and weapons. If added, the tool(s) is/are granted with the power of a furnace, meaning it will auto-smelt blocks when harvested. However, adding this to a weapon will not give it the same effect. Instead, it will set mobs on fire for 3 seconds.<BR>This modifier can be stacked with Luck (Fortune) and is not compatible with Silky (Silk Touch).");
mods.thaumcraft.Infusion.addRecipe("LAVACRYSTAL", <minecraft:fire_charge>, [<minecraft:blaze_rod>, <minecraft:lava_bucket>, <minecraft:fire_charge>, <Thaumcraft:ItemShard:1>, <minecraft:blaze_rod>, <minecraft:lava_bucket>, <minecraft:fire_charge>, <Thaumcraft:ItemShard:1>, <minecraft:blaze_rod>, <minecraft:lava_bucket>, <minecraft:fire_charge>, <Thaumcraft:ItemShard:1>], "ignis 25, perditio 25, vacuos 20, praecantatio 35", <TConstruct:materials:7>, 3);
mods.thaumcraft.Research.addInfusionPage("LAVACRYSTAL", <TConstruct:materials:7>);
mods.thaumcraft.Warp.addToResearch("LAVACRYSTAL", 1);

Display More

Mine_Sasha · Mar 8th 2015

Guys, sorry for bothering you again, but may I get help for minetweaker again, my script broke again...

Anyone interested into taking a look into my problem, please PM me so you can access the modpack & the script, I'm honestly tired as I can't figure out what is wrong ;P

DreamMasterXXL · Mar 8th 2015

mine Sasha

Why you don't attaching this script in your post or they are too many files? If you send me your scripts maybe i can help.

Mine_Sasha · Mar 8th 2015

KK, gonna give you the scripts, wait just a bit.

Smetanol · Mar 10th 2015

Display Spoiler

I solved it with my magnificent chicken brains . Turns out deal was in the unification file, it will preoritize stuff with =true over =false, I simply made *most of* TFC section =true and problem was solved. Lik dis if u cry evertim.

MauveCloud · Mar 10th 2015

Quote from Smetanol

Allright, I've got a problem.
There's such thing as FTB launcher and code "TerraFirmaTech" for private modpack.
It's about adding Gregtech and few other mods like AE3 in TerraFirmaCraft mod.
The problem is: gregtech unifies too much. First it was unifying everything I craft (which I solved with simple config tweaking). But it still unifying stuff i get from the world. As an example I placed pile of TerraFirmaCraft bronze ingots on floor, when I'm trying to take them in my inventory they become greg ingots. Same stuff happens with charcoal - when I dig TFC charcoal pit, it gives me minecraft charcoal instead of TFC charcoal, that required to make simple iron. As I can't get to iron making, I can't proceed with gregtech.(I can setup steam machines, and try to progress through gregtech that way, but it can be too problematic, being still in copper era).

So I need to find the switch, that will turn off world item unification.
P.S. Unification.cfg, consists out of =false only

Was trying to dellete stuff from Unification.cfg. Doesn't change anything.

Display More

I just did a brief test, and apparently you need to set the value to true in Unification.cfg (e.g. B:ingotBronze_false=true) to tell GregTech to avoid unifying the item. However, an alternative that would fit better with this thread would be to add some Minetweaker scripts so that the TFC recipes you're concerned with can use the unified items.

[MineTweaker-Scripts & Mod-Configs] Let's Greg other mods!

Share

Users Viewing This Thread